Školní programy v assembleru pro procesory 8051

Na střední škole jsme se učili programovat procesory 8051. Používali jsme k tomu assembler As51 [285kB]. Zde jsou některé ukázkové programy:

Součet 4 místných čísel

Jednoduchý podprogram, který sečte dvě čtyřmístná čísla ve formátu BCD.
Obsah souboru "sum4mc.asm":

Rozdíl 4 místných čísel

Jednoduchý podprogram, který spočítá rozdíl dvou čtyřmístných čísel ve formátu BCD.
Obsah souboru "rozdil4m.asm":

Součet řady 4 místných čísel

Podprogram pro součet řady (ve vnější paměti dat) čtyřmístných čísel ve formátu BCD. Výsledek je uložen jako 32bitové číslo.
Obsah souboru "sum_rady.asm":

; Secte radu ctyrmistnych cisel ve formatu BCD.
; Rada cisel je ukoncena znackou #0FFH.
; Vysledek je ulozen jako 32bitove BCD cislo

; Vstup:    DPTR - adresa prvniho cisla
; Vystup:   R2, R3, R4, R5 - soucet rady cisel
; Nici:     DPTR - po ukonceni podprogramu ukazuje
;                  na ukoncovaci znak #0FFH

ORG 0

Sum_rady:
	CLR A
	MOV R2, A	
	MOV R3, A	
	MOV R4, A
	MOV R5, A	; vynuluju vysledek
	
Cteni:	MOVX A, @DPTR	; prectu cislo z rady cisel
	CJNE A, #0FFH, Jedem	; neni v ACC #0FFH ???
        
        RET		; ACC = #0FFH  =>  hotovo !!!
		
Jedem:	ADD A, R5	; prictu k ACC nizsi byte vysledku
	DA A		; dekadicka korekce
	MOV R5, A	; ulozim ACC do nizsiho bytu vysl.
	
	INC DPTR
	MOVX A, @DPTR	; nactu vyssi byte z rady cisel
	ADDC A, R4	; prictu vyssi byte vysl. + CARRY
	DA A		; dekadicka korekce
	MOV R4, A	; ulozim ACC do vyssiho bytu vysl.
	
	CLR A
	ADDC A, R3
	DA A
	MOV R3, A
	
	CLR A
	ADDC A, R2
	DA A
	MOV R2, A
	
	INC DPTR	; posunu DPTR na dalsi cislo
	SJMP Cteni	; nactu dalsi cislo
		
	END

Sloučení řady 4 místných čísel

Podprogram, který sloučí řadu (ve vnější paměti dat) 2bytových čísel ve formátu BCD tak, že každé druhé číslo odečte a ostatní čísla přičte. Výsledek je 4bytový.
Obsah souboru "sluradu1.asm":

; Slouci radu 2bytovych cisel ve formatu BCD tak,
; ze kazde druhe cislo odecte.
; Rada cisel je ukoncena znackou #0FFH

; Vstup: DPTR = adresa prvniho cisla
; Vystup: R4, R5, R6, R7 = vysledek slouceni

org 0

Slucovani:
	clr a
	mov r4, a
	mov r5, a
	mov r6, a
	mov r7, a		; vynuluju vysledek
	
Pricti:
	movx a, @dptr		; nactu nejnizsi byte z rady
	cjne a, #0FFH, Pricti2	; neni to ukoncovaci znacka?
	ret			; a=#0FFH => konec
Pricti2:
	inc dptr		; posunu dtpr (pro pristi cteni)
	clr c			; vynuluju carry (kvuli dek. korekci)
	add a, r7		; sectu nejnizsi byte z rady a z vysledku
	da a			; dekadicka korekce
	mov r7, a		; ulozim nejnizsi byte vysledku
	
	movx a, @dptr		; nactu dalsi byte cisla z rady
	inc dptr		; posunu dptr (pro pristi cteni)
	addc a, r6		; sectu nacteny byte, vysledek a prenos
	da a			; dekadicka korekce
	mov r6, a		; ulozim vysledek
	
	clr a			; vynuluju Acc
	addc a, r5		; prictu k vysledku prenos
	da a			; dekadicka korekce
	mov r5, a		; ulozim vysledek
	
	clr a			; vynuluju Acc
	addc a, r4		; prictu k nejvyssimu bytu vysledku prenos
	da a			; dekadicka korekce
	mov r4, a		; ulozim nejvyssi byte vysledku

Odecti:
	movx a, @dptr		; nactu nejnizsi byte z rady
	cjne a, #0FFH, Odecti2	; neni to ukoncovaci znacka 0FFH ???
	ret			; jestli ano, tak koncime
Odecti2:
	inc dptr		; posunu dptr (pro pristi cteni)
	mov b, a		; presunu nacteny byte do registru B
	mov a, #9AH		; priprava na vypocet doplnku mensitele
	clr c			; vynuluju carry (kvuli odecitani)
	subb a, b		; vypocitam doplnek mensitele
	add a, r7		; doplnek mensitele + mensenec
	da a			; dekadicka korekce
	mov r7, a		; ulozim vysledek
	
	movx a, @dptr
	inc dptr
	mov b, a
	clr a
	addc a, #99H
	subb a, b
	add a, r6
	da a 
	mov r6, a
	
	clr a			; treti byte mensitele je nulovy
	addc a, #99H		; doplnek mensitele je #99H + prenos
	add a, r5		; doplnek mensitele + mensenec
	da a			; dekadicka korekce
	mov r5, a		; ulozim vysledek
	
	clr a
	addc a, #99H
	add a, r4
	da a
	mov r4, a
	
	jmp Pricti		; prictu dalsi cislo

END

Součet dvou řad (stejné délky) 4 místných čísel

Podprogram, který sečte odpovídající prvky dvou řad (Ai, Bi) a výsledkem je řada Ci. Vstupní čísla jsou čtyřmístná v BCD kódu, výstupní čísla jsou šestimístná, rovněž v BCD kódu. Všechny řady mají stejný počet prvků a jsou ukončené značkou #0FFH.
Obsah souboru "slurady.asm":

; Secte odpovidajici prvky dvou rad (Ai, Bi) 
;   a vysledkem je rada Ci.
; Vstupni cisla jsou ctyrmistna, v BCD kodu.
; Vystupni cisla jsou sestimistna v BCD kodu.
; Vsechny rady jsou stejne dlouhe, ukoncene znackou #0FFH.

; Vstupy:  R2, R3 = pocatecni adresa rady Ai
;          R4, R5 = pocatecni adresa rady Bi
;          R6, R7 = pocatecni adresa rady Ci

; Nici:  R0, R1 = aktualni soucet dvou cisel
;        vsechny vstupy

org 0
	
SectiRady:

; Nactu z vnejsi pameti dat 2bytove cislo z rady Ai
	; a ulozim jej do registru R0 a R1.
	; Zaroven kontroluji ukoncovaci znacku.

mov DPH, R2
	mov DPL, R3
	movx a, @dptr
	inc dptr
	cjne a, #0FFH, Pokracuj
	mov DPH, R6
	mov DPL, R7
	movx @dptr, a
	RET
Pokracuj:
	mov R1, a
	movx a, @dptr
	inc dptr
	mov R0, a
	mov R2, DPH
	mov R3, DPL
	
	; Nactu z vnejsi pameti dat 2bytove cislo z rady Bi
	; a prictu jej k cislu v registrech R0 a R1.
	; Prenos do vyssiho radu je ulozen v priznaku Carry.

mov DPH, R4
	mov DPL, R5
	movx a, @dptr
	inc dptr
	clr c
	add a, R1
	da a
	mov R1, a
	movx a, @dptr
	inc dptr
	addc a, R0
	da a
	mov R0, a
	mov R4, DPH
	mov R5, DPL
	
	; Ulozim soucet do rady Ci. 
	; Nejnizsi byte nacitam z registru R1,
	; dalsi byte z registru R0
	; a nejvyssi byte vytvarim z priznaku Carry.
	
	mov DPH, R6
	mov DPL, R7
	mov a, R1
	movx @dptr, a
	inc dptr
	mov a, R0
	movx @dptr, a
	inc dptr
	clr a
	jnc CJeNula
	mov a, #1
CJeNula:
	movx @dptr, a
	inc dptr
	mov R6, DPH
	mov R7, DPL
	
	; Cely proces se cyklicky opakuje
	
	jmp SectiRady
	
	
	END

Součet dvou řad (různé délky) 4 místných čísel

Podprogram, který sečte odpovídající prvky dvou řad (Ai, Bi) a výsledkem je řada Ci. Vstupní čísla jsou čtyřmístná v BCD kódu, výstupní čísla jsou šestimístná, rovněž v BCD kódu. Všechny řady jsou ukončené značkou #0FFH. Kratší řada se jakoby doplnění nulami, aby bylo možné využít i čísla z delší řady.
Obsah souboru "sum2r2.asm":

; Secte odpovidajici prvky dvou rad (Ai, Bi) 
;   a vysledkem je rada Ci.
; Vstupni cisla jsou ctyrmistna, v BCD kodu.
; Vystupni cisla jsou sestimistna v BCD kodu.
; vsechny rady jsou ukoncene znackou #0FFH.

; Vstupy:  R2, R3 = pocatecni adresa rady Ai
;          R4, R5 = pocatecni adresa rady Bi
;          R6, R7 = pocatecni adresa rady Ci

; Nici:  R0, R1 = aktualni soucet dvou cisel
;        vsechny vstupy

org 0
	
SectiRady:

; Nactu z vnejsi pameti dat 2bytove cislo z rady Ai
	; a ulozim jej do registru R0 a R1.
	; Zaroven kontroluji ukoncovaci znacku.

clr a
	mov R0, a
	mov R1, a
	mov DPH, R2
	mov DPL, R3
	movx a, @dptr
	inc dptr
	cjne a, #0FFH, Pokracuj
	; Zkontroluju, jestli nekonci i druha rada
	mov DPH, R4
	mov DPL, R5
	movx a, @dptr
	cjne a, #0FFH, PokrBi  ; a budeme nacitat z Bi
	mov DPH, R6
	mov DPL, R7
	movx @dptr, a
	RET
Pokracuj:
	mov R1, a
	movx a, @dptr
	inc dptr
	mov R0, a
	mov R2, DPH
	mov R3, DPL
	
	; Nactu z vnejsi pameti dat 2bytove cislo z rady Bi
	; a prictu jej k cislu v registrech R0 a R1.
	; Prenos do vyssiho radu je ulozen v priznaku Carry.
PokrBi:
	mov DPH, R4
	mov DPL, R5
	movx a, @dptr
	cjne a, #0FFH, PokrBi2
	clr c
	sjmp PokrCi ; Preskocim pricitani z Bi
PokrBi2:
	inc dptr
	clr c
	add a, R1
	da a
	mov R1, a
	movx a, @dptr
	inc dptr
	addc a, R0
	da a
	mov R0, a
	mov R4, DPH
	mov R5, DPL
	
	; Ulozim soucet do rady Ci. 
	; Nejnizsi byte nacitam z registru R1,
	; dalsi byte z registru R0
	; a nejvyssi byte vytvarim z priznaku Carry.
PokrCi:
	mov DPH, R6
	mov DPL, R7
	mov a, R1
	movx @dptr, a
	inc dptr
	mov a, R0
	movx @dptr, a
	inc dptr
	clr a
	jnc CJeNula
	mov a, #1
CJeNula:
	movx @dptr, a
	inc dptr
	mov R6, DPH
	mov R7, DPL
	
	; Cely proces se cyklicky opakuje
	
	jmp SectiRady
	
	
	END

Blikající LEDka

LED dioda připojená na pin P1.0 bliká s periodou 1 sekunda.
K tomuto programu navíc potřebujete knihovnu "delay.inc", jejíž obsah je uveden na konci této stránky.
Obsah souboru "led.asm":

Běhající světlo po osmi LEDkách

Na port P1 je připojených 8 LEDek. Jestli jste někdy viděli seriál Knight Rider, tak jste si jistě všimli běhajícího světla vepředu na autě. Tento program vytváří podobný vizuální efekt.
K tomuto programu navíc potřebujete knihovnu "delay.inc", jejíž obsah je uveden na konci této stránky.
Obsah souboru "led2.asm":

Řízení dopravy na křižovatce světelnými signály

Na pin P1.7 připojte červenou LED semaforu č. 1.
Na pin P1.6 připojte žlutou LED semaforu č. 1.
Na pin P1.5 připojte zelenou LED semaforu č. 1.
Na pin P1.4 připojte červenou LED semaforu č. 2.
Na pin P1.3 připojte žlutou LED semaforu č. 2.
Na pin P1.2 připojte zelenou LED semaforu č. 2.
Na pin P1.0 připojte tlačítko, kterým budete zapínat neřízenou dopravu (blikající žlutá světla).
K tomuto programu navíc potřebujete knihovnu "delay.inc", jejíž obsah je uveden na konci této stránky.
Obsah souboru "doprava.asm":

Knihovna pro vytváření časového zpoždění

Voláním procedury DEL1S vytvoříte zpoždění 1 sekunda.
Voláním procedury DEL800 vytvoříte zpoždění 800 milisekund.
Voláním procedury DEL400 vytvoříte zpoždění 400 milisekund.
Voláním procedury DEL200 vytvoříte zpoždění 200 milisekund.
Voláním procedury DEL100 vytvoříte zpoždění 100 milisekund.
Obsah souboru "delay.inc":

Martin Adamíra